关于FLASH制作的打字机效果和开始和结束按钮制作

Question

求高手详细教教如何用FLASH软件做出打字机效果的文字还有就是怎么制作开始和结束按钮，并且怎么用到文件中！详细的，好的，我会追加奖励的哦！

Answer 1

给你个打字效果的类吧
package com.jicemoon
{
import flash.display.Sprite;
import flash.events.TimerEvent;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.text.TextFormat;
import flash.utils.Timer;

public class TypeWriterEffect extends Sprite
{
private var words:String;
private var typeSpeed:uint;
private var timer:Timer;
private var tf:TextField;

private var currentWord:uint;
private var totalWords:uint;

/******
* @param-->str: 要打的字符串；
* @param-->textFormat: 文本框的格式，为一个TextFormat对象，不明白的话可以查看帮助；
* @param-->isStartType：是否在初始化的时候进行播放打字效果；
* @param-->speed：打字速度，以毫秒为单位默认为50，我测试的时候有点快。。。
* ****/
public function TypeWriterEffect(str:String, textFormat:TextFormat = null, isStartType:Boolean = false, speed:uint = 50)
{
this.words = str;
this.typeSpeed = speed;

this.currentWord = 0;
this.totalWords = this.words.length;

this.tf = new TextField();
tf.autoSize = TextFieldAutoSize.LEFT;
if(textFormat)
{
tf.defaultTextFormat = textFormat;
}
//tf.text = this.words;
this.addChild(tf);
this.timer = new Timer(this.typeSpeed);
this.timer.addEventListener(TimerEvent.TIMER, onTimerEventHandle);
if(isStartType)
{
this.start();
}
}
/************开始播放打字效果***********/
public function start():void
{
if(this.timer)
{
this.timer.start();
}
}
/**********停止播放打字效果*************/
public function stop():void
{
if(this.timer)
{
this.timer.stop();
this.timer.reset()
} ;
}
/***********重置打字效果
* @param-->str：重置要显示的字符串；
* @param-->isStartType：是否重置后立即开始打字效果，默认为是（true）；
* ************/
public function resetWords(str:String, isStartType:Boolean = true):void
{
this.stop();
this.tf.text = "";
if(isStartType)
{
this.start();
}
}
private function onTimerEventHandle(evt:TimerEvent):void
{
this.tf.appendText(this.words.charAt(this.currentWord));
this.currentWord++;
if(this.currentWord >= this.totalWords)
{
this.timer.stop();
}
}
}
}
这个是AS3写的，下面是使用方法
var tf:TextFormat = new TextFormat();
tf.size = 40;
tf.align = TextFormatAlign.LEFT;
tf.color = 0xff0000;

var tw:TypeWriterEffect = new TypeWriterEffect("by jicemoon", tf, true);
this.addChild(tw);
如果要添加开始和结束按钮，只需要在相应按钮的点击事件监听函数中调用相应的方法就行了，不明白的话，请追问。。。。。

Answer 2

打字机效果向他说的可以这么做，用代码的话比较复杂估计你也看不懂。开始按钮可以做将代码设置给按钮：play();括号和分号必须是英文的，中文的不能用。结束按钮的代码是：stop();同样设置给按钮。不过这种设置一般叫暂停按钮。还有要看你的flash 是什么版本的AS2.0跟3.0的控制方法不一样。

Answer 3

问题好几个，不是一言两语能说清楚的。
打字效果就是打一段文字，然后打散一次，快捷键CTRL+B，然后做逐帧动画。
按钮就是做一个按钮元件，你说的开始应该是需要点击以后动画才开始吧，那需要在按钮上加入跳转的代码命令，比较复杂。本回答被网友采纳